 |
 |
Общие сведения:
Модуль твердотельных реле на 4 канала, I2C, Flash - является устройством коммутации, которое позволяет подключать и отключать устройства к сети переменного тока от 120В до 240В. При этом устройства подключённые через выходные контакты модуля, не должны потреблять более 2А переменного тока (на каждый канал).
Управление модулем осуществляется по шине I2C. Модуль относится к линейке «Flash», а значит к одной шине I2C можно подключить более 100 модулей, так как их адрес на шине I2C (по умолчанию 0x09), хранящийся в энергонезависимой памяти, можно менять программно.
Модуль можно использовать в любых проектах где требуется управлять устройствами с напряжением питания от 120В до 240В и потреблением переменного тока до 2А.
Видео:
Спецификация:
- Напряжение питания: 5 В (постоянного тока).
- Потребляемый ток: до 20 мА.
- Коммутируемое напряжение: от 120 В до 250 В (переменного тока).
- Коммутируемый ток: до 2 А (на каждый канал).
- Количество каналов: 4.
- Интерфейс: I2C.
- Скорость шины I2C: 100 кбит/с.
- Адрес на шине I2C: устанавливается программно (по умолчанию 0x09).
- Уровень логической 1 на линиях шины I2C: 3,3 В (толерантны к 5 В).
- Рабочая температура: от -40 до +65 °C.
- Габариты с креплением: 55 х 55 мм.
- Габариты без креплений: 55 х 45 мм.
- Вес: 30 г.
Подключение:
Перед подключением модуля ознакомьтесь с разделом "Смена адреса модуля на шине I2C" в данной статье.
В левой части платы расположены два разъема для подключения модуля к шине I2C. Шина подключается к любому разъему I2C, а второй разъем можно использовать для подключения следующего модуля твердотельных реле, или других устройств.
- SCL - вход/выход линии тактирования шины I2C.
- SDA - вход/выход линии данных шины I2C.
- Vcc - вход питания модуля 5В.
- GND - общий вывод питания.
В правой части платы расположены четыре разъема: K1, K2, K3, K4, это выходы, через контакты которых подключаются силовые устройства к сети переменного тока от 120В до 250В. Устройства не должны потреблять более 2А (на каждый канал).
- K1 - разъём первого реле с нормально разомкнутыми «NO» (Normally Open) контактами.
- K2 - разъём второго реле с нормально разомкнутыми «NO» (Normally Open) контактами.
- K3 - разъём третьего реле с нормально разомкнутыми «NO» (Normally Open) контактами.
- K4 - разъём четвёртого реле с нормально разомкнутыми «NO» (Normally Open) контактами.
Для удобства подключения к Arduino воспользуйтесь Trema Shield, Trema Power Shield или Motor Shield.
Способ - 1: Используя провода и Piranha UNO
Используя провода «Папа — Мама», подключаем напрямую к контроллеру Piranha UNO
Способ - 2: Используя проводной шлейф и Trema Shield
Используя 4-х проводной шлейф подключаем к Trema Shield
Способ - 3: Подключение к программной шине I2C
При использовании программной шины I2C, модуль можно подключить к любым выводам Arduino, но потребуется дополнительно установить библиотеку iarduino_I2C_Software.h, для создания программной шины I2C, указав номера выбранных вами выводов. О том как это сделать читайте ниже в разделе «Подключение библиотеки», а так же на странице Wiki - Расширенные возможности библиотек iarduino для шины I2C.
Подключение нескольких устройств
Благодаря шине I2C возможно подключение более 100 устройств:
Подключение нагрузки:
При включении нагрузки загорается светодиод соответствующего канала:
Питание:
Входное напряжение питания логической части модуля, 5В постоянного тока, подаётся на выводы Vcc и GND любого разъёма шины I2C.
Подробнее о модуле:
Модуль твердотельных реле на 4 канала, I2C, Flash построен на базе микроконтроллера STM32F030F4, снабжен собственным стабилизатором напряжения и четырьмя твердотельными реле.
Силовые устройства подключаются к сети переменного тока (от 120В до 240В) через контакты разъемов «K1», «K2», «K3», «K4».
- О состоянии реле можно судить по светодиодам расположенным рядом с реле.
- Если светодиод выключен, значит реле отключено и его выводы разъединены.
- Если светодиод светится, значит реле включено и его выводы замкнуты.
Специально для работы с модулями силовых ключей и реле, нами разработана библиотека iarduino_I2C_Relay которая позволяет реализовать все функции модуля.
Подробнее про установку библиотеки читайте в нашей инструкции.
Смена адреса модуля на шине I2C:
По умолчанию все модули FLASH-I2C имеют установленный адрес 0х09. Если вы планируете подключать более 1 модуля на шину I2C, необходимо изменить адреса модулей таким образом, чтобы каждый из них был уникальным. Более подробно о том, как изменить адрес, а также о многом другом, что касается работы FLASH-I2C модулей, вы можете прочесть в этой статье.
В первой строке скетча необходимо записать в переменную newAddress адрес, который будет присвоен модулю. После этого подключите модуль к контроллеру и загрузите скетч. Адрес может быть от 0х07 до 0х7F.
uint8_t newAddress = 0x09; // Назначаемый модулю адрес (0x07 < адрес < 0x7F).
//
#include <Wire.h> // Подключаем библиотеку для работы с аппаратной шиной I2C, до подключения библиотеки iarduino_I2C_Relay.
#include <iarduino_I2C_Relay.h> // Подключаем библиотеку для работы с модулем
iarduino_I2C_Relay relay; // Создаём объект для работы с функциями и методами библиотеки.
// Если при объявлении объекта указать адрес, например, module(0xBB), то пример будет работать с тем модулем, адрес которого был указан.
void setup(){ //
Serial.begin(9600); //
if( relay.begin(&Wire) ){ // Инициируем работу с модулем, указав ссылку на объект для работы с шиной I2C на которой находится индикатор (по умолчанию &Wire).
Serial.print("На шине I2C найден модуль с адресом 0x"); //
Serial.print( relay.getAddress(), HEX ); // Выводим текущий адрес модуля.
Serial.print(" который является твердотельным реле\r\n"); //
if( relay.changeAddress(newAddress) ){ // Меняем адрес модуля на newAddress.
Serial.print("Адрес модуля изменён на 0x"); //
Serial.println( relay.getAddress(), HEX ); // Выводим текущий адрес модуля.
}else{ //
Serial.println("Адрес модуля изменить не удалось!"); //
} //
}else{ //
Serial.println("модуль не найден!"); //
} //
} //
//
void loop(){} //
Данный пример использует библиотеку iarduino_I2C_Relay, которая работает только с модулями силовых ключей и реле, а значит позволяет менять только их адреса.
Смена и сортировка адресов на шине I2C:
Изменить адрес любого I2C модуля серии «Flash» можно аппаратно, используя установщик адресов FLASH-I2C. Это модуль подключаемый к шине I2C, на плате которого размещён дисплей и кнопки управления, при помощи которых можно узнать количество любых устройств на шине I2C, и менять адреса модулей Flash-I2C не отключая их от шины, что значительно сократит время сборки ваших проектов. Модуль оснащён разъемом USB через который можно запитать как сам модуль, так и шину I2C, или можно запитать шину I2C без использования разъема USB на плате модуля. Установщик адресов пригодиться в проектах с большим количеством модулей Flash-I2C.
Изменить адрес любого I2C модуля серии «Flash» можно программно, о том как это сделать рассказано в статье Wiki - Программная установка адресов модулей FLASH-I2C. В этой статье рассмотрены примеры с использованием библиотеки iarduino_I2C_Address, которая позволяет получать адреса любых устройств на шине I2C, менять адреса модулей Flash-I2C не отключая их от шины, получать название, номер модели, версию прошивки модулей Flash-I2C, а главное - автоматически сортировать адреса модулей Flash-I2C даже если на шине есть устройства с одинаковыми адресами.
Примеры:
В данном разделе раскрыты примеры работы с модулем по шине I2C с использованием библиотеки iarduino_I2C_Relay. Сама библиотека содержит больше примеров, доступных из меню Arduino IDE: Файл / Примеры / iarduino_I2C_Relay.
Поочерёдное включение и выключение реле модуля:
#include <Wire.h> // Подключаем библиотеку для работы с аппаратной шиной I2C, до подключения библиотеки iarduino_I2C_Relay.
#include <iarduino_I2C_Relay.h> // Подключаем библиотеку для работы с реле и силовыми ключами.
iarduino_I2C_Relay relay(0x09); // Создаём объект relay для работы с функциями и методами библиотеки iarduino_I2C_Relay, указывая адрес модуля на шине I2C.
// Если объявить объект без указания адреса (iarduino_I2C_Relay relay;), то адрес будет найден автоматически.
void setup(){ //
relay.begin(); // Инициируем работу с модулем.
relay.digitalWrite(ALL_CHANNEL,LOW); // Выключаем все каналы модуля.
} //
//
void loop(){ //
relay.digitalWrite(1,HIGH); relay.digitalWrite(4,LOW); // Включаем 1 канал и выключаем 4.
delay(500); // Ждём 500 мс.
relay.digitalWrite(2,HIGH); relay.digitalWrite(1,LOW); // Включаем 2 канал и выключаем 1.
delay(500); // Ждём 500 мс.
relay.digitalWrite(3,HIGH); relay.digitalWrite(2,LOW); // Включаем 3 канал и выключаем 2.
delay(500); // Ждём 500 мс.
relay.digitalWrite(4,HIGH); relay.digitalWrite(3,LOW); // Включаем 4 канал и выключаем 3.
delay(500); // Ждём 500 мс.
} //
Данный пример будет поочерёдно включать и выключать реле.
Чтение состояний реле модуля:
#include <Wire.h> // Подключаем библиотеку для работы с аппаратной шиной I2C, до подключения библиотеки iarduino_I2C_Relay.
#include <iarduino_I2C_Relay.h> // Подключаем библиотеку для работы с реле и силовыми ключами.
iarduino_I2C_Relay relay(0x09); // Создаём объект relay для работы с функциями и методами библиотеки iarduino_I2C_Relay, указывая адрес модуля на шине I2C.
// Если объявить объект без указания адреса (iarduino_I2C_Relay relay;), то адрес будет найден автоматически.
void setup(){ //
Serial.begin(9600); // Инициируем передачу данных в монитор последовательного порта на скорости 9600 бит/сек.
relay.begin(); // Инициируем работу с модулем.
// Включаем и выключаем каналы модуля: //
relay.digitalWrite(1, LOW); // Отключаем 1 канал.
relay.digitalWrite(2, HIGH); // Включаем 2 канал.
relay.digitalWrite(3, LOW); // Отключаем 3 канал.
relay.digitalWrite(4, HIGH); // Включаем 4 канал.
// Проверяем состояние каналов модуля в цикле: //
for(int i=1; i<=4; i++){ Serial.print ("Канал N "); // Проходим по всем каналам модуля.
Serial.print (i); // Выводим номер очередного канала.
if(relay.digitalRead(i)){Serial.println(" включен ");} // Если функция digitalRead() вернула HIGH значит канал включён.
else {Serial.println(" отключен");} // Если функция digitalRead() вернула LOW значит канал отключён.
} Serial.println("---------"); //
} //
//
void loop(){} //
//
// ПРИМЕЧАНИЕ: //
// состояние всех реле модуля можно получить одним байтом: //
// uint8_t j = relay.digitalRead(ALL_CHANNEL); // 4 младших бита переменной «j» соответствуют состояниям 4 каналов модуля.
Данный пример считывает состояние реле и выводит их в монитор последовательного порта.
Защита от зависаний Arduino и отключения шины I2C:
#include <Wire.h> // Подключаем библиотеку для работы с аппаратной шиной I2C, до подключения библиотеки iarduino_I2C_Relay.
#include <iarduino_I2C_Relay.h> // Подключаем библиотеку для работы с реле и силовыми ключами.
iarduino_I2C_Relay relay(0x09); // Создаём объект relay для работы с функциями и методами библиотеки iarduino_I2C_Relay, указывая адрес модуля на шине I2C.
// Если объявить объект без указания адреса (iarduino_I2C_Relay relay;), то адрес будет найден автоматически.
void setup(){ //
Serial.begin(9600); // Инициируем передачу данных в монитор последовательного порта на скорости 9600 бит/сек.
relay.begin(); // Инициируем работу с модулем.
relay.enableWDT(5); // Разрешаем работу сторожевого таймера модуля, задав время до перезагрузки 5 сек.
} // Отключить работу сторожевого таймера модуля можно функцией disableWDT().
//
void loop(){ //
// Переключаем 1 и 2 каналы модуля: //
relay.digitalWrite(1,HIGH); relay.digitalWrite(2,LOW); delay(500); // Включаем 1 канал, выключаем 2 канал и ждём 500 мс.
relay.digitalWrite(2,HIGH); relay.digitalWrite(1,LOW); delay(500); // Включаем 2 канал, выключаем 1 канал и ждём 500 мс.
// Сбрасываем (перезапускаем) сторожевой таймер модуля: //
relay.resetWDT(); // Теперь таймер модуля начнёт заново отсчитывать 5 секунд до перезагрузки.
// Сообщаем, что сработал сторожевой таймер: //
if( relay.getStateWDT() == false ){ Serial.println("ERROR"); } // Если таймер отключился, значит он досчитал до 0 и перезагрузил модуль отключив все его каналы.
} // Если модуль не отвечает (отключилась шина I2C), то функция getStateWDT() так же вернёт false.
При нормальной работе данного примера, в первую половину секунды включено первое реле, а во вторую половину секунды включено второе реле.
Если отключить от модуля вывод SDA или SCL шины I2C, то реле перестанут переключаться, но одно из реле останется включённым. Подождав от 4 до 5 секунд, сработает сторожевой таймер модуля и все реле отключатся. Время ожидания зависит от того, в каком месте выполнения кода был отключён вывод.
Примечание: Время назначенное сторожевому таймеру функцией enableWDT() должно быть больше чем время между вызовами функции resetWDT().
Определение модуля на шине I2C и изменение его адреса:
uint8_t i = 0x09; // Назначаемый модулю новый адрес (0x07 < адрес < 0x7F).
#include <Wire.h> // Подключаем библиотеку для работы с аппаратной шиной I2C, до подключения библиотеки iarduino_I2C_Relay.
#include <iarduino_I2C_Relay.h> // Подключаем библиотеку для работы с реле и силовыми ключами.
iarduino_I2C_Relay relay; // Создаём объект relay для работы с функциями и методами библиотеки iarduino_I2C_Relay.
// Если при объявлении объекта указать адрес, например, relay(0xBB); то пример будет работать с тем модулем, адрес которого был указан.
void setup(){
Serial.begin(9600); Serial.print( "На шине I2C " );
// Инициируем работу с модулем: (метод relay.begin(); вернёт true при успехе).
if( relay.begin() ){ Serial.print( "найден модуль с адресом 0x" );
Serial.print( relay.getAddress(), HEX );
Serial.print( ", который является " );
// Выводим информацию о модуле:
switch( relay.getModel() ){
case DEF_MODEL_2RM: Serial.print( "электромеханическим реле на 2-канала" );
case DEF_MODEL_4RT: Serial.print( "твердотельным реле на 4-канала" );
case DEF_MODEL_4NC: Serial.print( "силовым ключом на 4 N-канала с измерением тока" );
case DEF_MODEL_4PC: Serial.print( "силовым ключом на 4 P-канала с измерением тока" );
case DEF_MODEL_4NP: Serial.print( "силовым ключом на 4 N-канала до 10A" );
case DEF_MODEL_4PP: Serial.print( "силовым ключом на 4 P-канала до 10A" );
default: Serial.print( "неизвестным силовым ключом или реле" );
} Serial.print( ".\r\n" );
// Меняем адрес модуля на «i»: (метод relay.changeAddress(новый адрес); вернёт true при успехе).
if(relay.changeAddress(i)){ Serial.print( "Адрес модуля изменён на 0x" ); // Меняем адрес модуля на указанный в переменной i.
Serial.print( relay.getAddress(), HEX ); // Выводим текущий адрес модуля.
Serial.print( " и сохранён в flash память модуля." );
}else{ Serial.print( "Адрес модуля изменить не удалось!" ); } // Если метод relay.changeAddress() вернул false, значит библиотеке не удалось сменить адрес модуля.
}else{ Serial.print( "нет ни силовых ключей, ни реле!" ); } // Если метод relay.begin() вернул false, значит библиотеке не удалось найти модуль реле или силовых ключей.
Serial.print( "\r\n" );
}
void loop(){}
Для работы этого примера необходимо что бы на шине I2C был только один модуль.
В первой строке скетча определяется переменная «i» с указанием адреса которой будет присвоен модулю (это значение Вы можете изменить на то, которое требуется Вам).
Данный пример определяет тип модуля, его текущий адрес и присваивает модулю новый адрес на шине I2C.
Описание функций библиотеки:
В данном разделе описаны функции библиотеки iarduino_I2C_Relay для работы с модулями реле.
Данная библиотека может использовать как аппаратную, так и программную реализацию шины I2C. О том как выбрать тип шины I2C рассказано в статье Wiki - расширенные возможности библиотек iarduino для шины I2C.
Подключение библиотеки:
- Если используется аппаратная шина I2C:
#include <Wire.h> // Подключаем библиотеку для работы с аппаратной шиной I2C, до подключения библиотеки iarduino_I2C_Relay.h
#include <iarduino_I2C_Relay.h> // Подключаем библиотеку для работы с модулями реле.
//
iarduino_I2C_Relay relay(0x09); // Создаём объект relay для работы с функциями и методами библиотеки iarduino_I2C_Relay, указывая адрес модуля на шине I2C.
// iarduino_I2C_Relay relay; // Если адрес модуля не известен, то его можно не указывать, он будет найден автоматически.
// Если адрес не указан, то на шине должен находиться только один модуль реле.
void setup(){ //
... //
relay.begin(&Wire); // Инициируем работу с модулем, указав ссылку на объект для работы с шиной I2C на которой находится модуль (по умолчанию &Wire).
... // Доступны объекты: &Wire, &Wire1, &Wire2...
} //
- Если используется программная шина I2C:
#include <iarduino_I2C_Software.h> // Подключаем библиотеку для работы с программной шиной I2C, до подключения библиотеки iarduino_I2C_Relay.h
SoftTwoWire sWire(3,4); // Создаём объект программной шины I2C указав выводы которым будет назначена роль линий: SDA, SCL.
//
#include <iarduino_I2C_Relay.h> // Подключаем библиотеку для работы с модулями реле.
iarduino_I2C_Relay relay(0x09); // Создаём объект relay для работы с функциями и методами библиотеки iarduino_I2C_Relay, указывая адрес модуля на шине I2C.
// iarduino_I2C_Relay relay; // Если адрес модуля не известен, то его можно не указывать, он будет найден автоматически.
// Если адрес не указан, то на шине должен находиться только один модуль реле.
void setup(){ //
... //
relay.begin(&sWire); // Инициируем работу с модулем, указав ссылку на объект для работы с шиной I2C на которой находится модуль (по умолчанию &Wire).
... //
} //
- В обоих примерах сначала подключается библиотека для работы с шиной I2C. Для аппаратной шины библиотека
Wire.h(предустановлена в Arduino IDE), а для программной шины библиотека iarduino_I2C_Software.h. с созданием объекта которому указываются выбранные вами выводы шины, в примере выводы(3-SDA, 4-SCL). - Далее подключается библиотека и создаётся объект для работы с модулем.
- В коде
Setup(), при инициализации работы с модулем указывается ссылка на объект работы с выбранной шиной I2Cbegin(&ШИНА). Остальные строки кода одинаковы для любой шины I2C.
Функция begin();
- Назначение: Инициализация работы с модулем.
- Синтаксис: begin();
- Параметры:
- &ШИНА - Ссылка на объект для работы с шиной I2C на которой находится модуль.
- Для аппаратной шины: &Wire, &Wire1, &Wire2..., если подключена библиотека Wire.h
- Для программной шины: ссылка на объект библиотеки iarduino_I2C_Software.h.
- Параметр является не обязательным, по умолчанию используется ссылка &Wire.
- Возвращаемое значение: bool - результат инициализации (true или false).
- Примечание: По результату инициализации можно определить наличие модуля на шине.
- Пример:
if( relay.begin(&Wire) ){ Serial.print( "Модуль найден и инициирован!" ); }
else { Serial.print( "Модуль не найден на шине I2C" ); }
Функция reset();
- Назначение: Перезагрузка модуля.
- Синтаксис: reset();
- Параметры: Нет.
- Возвращаемое значение: bool - результат перезагрузки (true или false).
- Пример:
if( relay.reset() ){ Serial.print( "Модуль перезагружен" ); }
else { Serial.print( "Модуль не перезагружен" ); }
Функция changeAddress();
- Назначение: Смена адреса модуля на шине I2C.
- Синтаксис: changeAddress( АДРЕС );
- Параметры:
- uint8_t АДРЕС - новый адрес модуля на шине I2C (целое число от 0x08 до 0x7E)
- Возвращаемое значение: bool - результат смены адреса (true или false).
- Примечание: Текущий адрес модуля можно узнать функцией getAddress().
- Пример:
if( relay.changeAddress(0x12) ){ Serial.print( "Адрес модуля изменён на 0x12" ); }
else { Serial.print( "Не удалось изменить адрес" ); }
Функция getAddress();
- Назначение: Запрос текущего адреса модуля на шине I2C.
- Синтаксис: getAddress();
- Параметры: Нет.
- Возвращаемое значение: uint8_t АДРЕС - текущий адрес модуля на шине I2C (от 0x08 до 0x7E)
- Примечание: Функция может понадобиться если адрес модуля не указан при создании объекта, а обнаружен библиотекой.
- Пример:
Serial.print( "Адрес модуля на шине I2C = 0x"); Serial.println( relay.getAddress(), HEX );
Функция getVersion();
- Назначение: Запрос версии прошивки модуля.
- Синтаксис: getVersion();
- Параметры: Нет
- Возвращаемое значение: uint8_t ВЕРСИЯ - номер версии прошивки от 0 до 255.
- Пример:
Serial.print( "Версия прошивки модуля "); Serial.println( relay.getVersion(), HEX );
Функция getModel();
- Назначение: Запрос типа модуля.
- Синтаксис: getModel();
- Параметры: Нет.
- Возвращаемое значение: uint8_t МОДЕЛЬ - идентификатор модуля от 0 до 255.
- Примечание: По идентификатору можно определить тип модуля (см. пример).
- Пример:
switch( relay.getModel() ){
case DEF_MODEL_2RM: Serial.print( "электромеханическое реле на 2-канала" ); break;
case DEF_MODEL_4RT: Serial.print( "твердотельное реле на 4-канала" ); break;
case DEF_MODEL_4NC: Serial.print( "силовой ключ на 4 N-канала с измерением тока" ); break;
case DEF_MODEL_4PC: Serial.print( "силовой ключ на 4 P-канала с измерением тока" ); break;
case DEF_MODEL_4NP: Serial.print( "силовой ключ на 4 N-канала до 10A" ); break;
case DEF_MODEL_4PP: Serial.print( "силовой ключ на 4 P-канала до 10A" ); break;
default: Serial.print( "неизвестный модуль" ); break;
}
Функция digitalWrite();
- Назначение: Включение/выключение одного или всех реле модуля.
- Синтаксис: digitalWrite( РЕЛЕ , СОСТОЯНИЕ );
- Параметры:
- uint8_t РЕЛЕ - номер реле модуля, от 1 до 4, или значение ALL_CHANNEL.
- uint8_t СОСТОЯНИЕ - значение 1 (включено) или 0 (отключено).
- Возвращаемое значение: Нет.
- Примечание: Функция включает или отключает реле.
- Пример:
relay.digitalWrite( ALL_CHANNEL, 0 ); // Отключить все реле. relay.digitalWrite( 2, 1 ); // Включить второе реле.
Функция digitalRead();
- Назначение: Чтение состояния одного из реле модуля.
- Синтаксис: digitalRead( РЕЛЕ );
- Параметры:
- uint8_t РЕЛЕ - номер реле модуля, значение от 1 до 4.
- Возвращаемое значение: uint8_t СОСТОЯНИЕ - значение 1 или 0.
- Примечание:
- Функция возвращает состояние установленное функцией digitalWrite().
- Пример:
Serial.print( "Первое реле модуля ");
if( relay.digitalRead( 1 ) ){ Serial.println( "включено " ); }
else { Serial.println( "отключено "); }
Дополнительные функции библиотеки:
Данные функции не являются основными, но могут быть полезны.
Функция enableWDT();
- Назначение: Запуск (разрешение работы) сторожевого таймера модуля.
- Синтаксис: enableWDT( ВРЕМЯ );
- Параметры:
- uint8_t ВРЕМЯ - количество секунд от 1 до 254.
- Возвращаемое значение: bool - результат запуска сторожевого таймера (true или false).
- Примечание:
- После выполнения функции, сторожевой таймер начнёт отсчитывать время, от указанного до 0. Обнуление сторожевого таймера приведёт к перезагрузке модуля и, как следствие, отключению всех его каналов.
- Если в процессе выполнения скетча, постоянно обращаться к функции enableWDT() (или resetWDT(), см. ниже), то таймер не сможет досчитать до 0, пока корректно работает скетч и шина I2C.
- Пример:
relay.enableWDT( 10 ); // Через 10 секунд модуль перезагрузится.
Функция disableWDT();
- Назначение: Отключение (запрет работы) сторожевого таймера модуля.
- Синтаксис: disableWDT();
- Параметры: Нет.
- Возвращаемое значение: bool - результат отключения сторожевого таймера (true или false).
- Примечание:
- Обращение к функции отключает сторожевой таймер без перезагрузки модуля.
- Пример:
relay.disableWDT(); // Отключение сторожевого таймера.
Функция resetWDT();
- Назначение: Сброс (перезагрузка) сторожевого таймера.
- Синтаксис: resetWDT();
- Параметры: Нет
- Возвращаемое значение: bool - результат перезагрузки сторожевого таймера (true или false).
- Примечание:
- Функция сбрасывает время сторожевого таймера в значение которое было определено ранее функцией enableWDT(), значит таймер начнёт отсчёт времени заново.
- К функции resetWDT() можно обращаться только если сторожевой таймер уже запущен, в противном случае функция resetWDT() вернёт false.
- Пример:
relay.enableWDT( 10 ); // Через 10 секунд модуль перезагрузится; delay(9000); // Ждём 9 секунд. relay.resetWDT(); // Модуль перезагрузится не через 1 секунду, а через 10.
Функция getStateWDT();
- Назначение: Чтение состояния сторожевого таймера.
- Синтаксис: getStateWDT();
- Параметры: Нет.
- Возвращаемое значение: bool - выполняется отсчёт времени (true или false).
- Примечание:
- Если таймер запущен функцией enableWDT() и не отключался функцией disableWDT(), а функция getStateWDT() вернула false, значит таймер досчитал до 0, и перезагрузил модуль.
- Если модуль не отвечает, например, отключилась шина I2C, то функция getStateWDT() так же вернёт false.
- Пример:
if( relay.getStateWDT() ){ Serial.println( "таймер выполняет отсчёт времени." ); }
else { Serial.println( "сторожевой таймер отключен."); }
Ссылки:
- Модуль твердотельных реле на 4 канала, I2C, Flash.
- Wiki - Модуль твердотельное реле, 4 канала, I2C, Flash - Datasheet.
- Библиотека iarduino_I2C_Relay.
- Библиотека iarduino_I2C_Software.
- Wiki - Расширенные возможности библиотек iarduino для шины I2C.
- Wiki - Установка библиотек в Arduino IDE.
- Wiki - Программная установка адресов модулей FLASH-I2C.
Обсуждение